Моделирование влияния преобразователей на сеть в среде системы Design — PSpice. Часть III

3.4. Интегральный графический символ и макромодель трехфазной мостовой схемы

Современные мощные полупроводниковые преобразователи выполняются на основе трехфазных мостовых схем соединения силовых полупроводниковых приборов. При моделировании влияния преобразователей на качество электроэнергии в сети целесообразно представлять преобразователь в виде единого интегрального компонента, включающего как элементы силовой схемы, так и системы управления, поскольку в данной задаче предметом анализа являются параметры напряжения в точке присоединения преобразователя к сети, а не электромагнитные процессы в самом преобразователе. Затраты интеллектуальной энергии на этапе создания интегрального компонента преобразователя компенсируется на этапе моделирования сложных электротехнических комплексов и систем, содержащих преобразователи, за счет упрощения технологии моделирования и сокращения затрат машинного времени на производство вычислений.

Рассмотрим технологию создания интегрального графического символа преобразователя, выполненного по трехфазной мостовой схеме, на основе его функциональной схемы (рис. 16, см. «СЭ» № 4’2005).

Макромодель интегрального графического символа преобразователя, выполненного по трехфазной мостовой схеме, реализована на базе трех компонентов: макромодели тиристора, макромодели системы управления, макромодели RC-цепи.

Текстовое описание макромодели системы управления в рассматриваемой задаче является составной частью текстового описания макромодели трехфазной мостовой схемы.

Полное текстовое описание макромодели трехфазной мостовой схемы на языке программы PSpice имеет вид:

.SUBCKT    Most_500_ISOL    A B C    da dk

• .SUBCKT — директива начала описания макромодели;
• Most_500_ISOL — имя макромодели;
• A, B, C, da, dk — маркировки узлов (выводов) трехфазной мостовой схемы, где A, B, C — выводы фаз A, B, C;
• da, dk — анодный и катодный выводы.

+ PARAMS:VALUE_ALFHA=30
VALUE_TETA_0=30 VALUE_FREQ=500

• PARAMS: — ключевое слово, после которого приводится перечень параметров макромодели;
• VALUE_ALFHA=30 — значение угла управления по умолчанию, размерность — электрический градус;
• VALUE_TETA_0=30 — значение сдвига точки отсчета угла управления относительно нуля системы координат по умолчанию, размерность — электрический градус.
• VALUE_FREQ=500 — значение частоты по умолчанию, размерность — Гц.

X_VS1 A  G1 dk SCR_m2_9
X_VS2 da G2 C  SCR_m2_9
X_VS3 B  G3 dk SCR_m2_9
X_VS4 da G4 A  SCR_m2_9
X_VS5 C  G5 dk SCR_m2_9
X_VS6 da G6 B  SCR_m2_9

• шесть предложений, описывающих соединение тиристоров в трехфазную мостовую схему:
• X_VS1… X_VS6 — имена тиристоров; первая буква имени «X» по правилам языка программы PSpice обозначает, что данный компонент описан макромоделью;
• A, B, C, G1… G6, da, dk — маркировки узлов (выводов) трехфазной мостовой схемы, к которым подключены тиристоры;
• SCR_m2_9 — имя макромодели тиристора.

X1 A dk RC PARAMS: R=1000 C=0.1u
X3 B dk RC PARAMS: R=1000 C=0.1u
X5 C dk RC PARAMS: R=1000 C=0.1u
X4 A da RC PARAMS: R=1000 C=0.1u
X6 B da RC PARAMS: R=1000 C=0.1u
X2 C da RC PARAMS: R=1000 C=0.1u

• шесть предложений, описывающих подключение демпфирующих RC-цепей параллельно тиристорам:
• X1…X6 — имена RC-цепей;
• A, B, C, da, dk — маркировки узлов (выводов) трехфазной мостовой схемы, к которым подключены RC-цепи;
• RC — имя макромодели RC-цепи;
• R = 1000, C = 0.1u — параметры RC-цепи: 1000 Ом, 0,1 мкФ.

XCS1  dk G1  C G2 dk G3 A G4 dk G5 B G6
+ System_a1_500_ISOL
+ PARAMS:     Tu=75      T0={VALUE_TETA_0}
+ A={VALUE_ALFHA}   Fr={VALUE_FREQ}

• предложение, описывающее соединение системы управления с тиристорами трехфазной мостовой схемы:
• XCS1 — имя системы управления;
• dk, G1, C, G2, dk, G3, A, G4, dk, G5, B, G6 — маркировки узлов (выводов) системы управления, которые подключены к тиристорам;
• System_a1_500_ISOL — имя макромодели системы управления.
• PARAMS: — ключевое слово, после которого приводится перечень параметров макромодели;
• Tu=75 — значение длительности управляющего импульса по умолчанию, размерность — электрический градус;
• T0={VALUE_TETA_0} — значение сдвига точки отсчета угла управления А относительно нуля системы координат, заданное идентификатором параметра VALUE_TETA_0, по умолчанию равно 30 электрическим градусам;
• A={VALUE_ALFHA} — значение угла управления, заданное идентификатором параметра VALUE_ALFHA; по умолчанию равно 30 электрическим градусам;
• Fr={VALUE_FREQ} — значение частоты по умолчанию, заданное идентификатором параметра VALUE_FREQ, по умолчанию равно 500 Гц.

.ENDS   Most_500_ISOL

• .ENDS — директива окончания описания макромодели;
• Most_500_ISOL — имя макромодели.

В тексте макромодели «Most_500_ISOL» используются текстовые описания двух компонентов: макромодели RC-цепи — «RC» и макромодели системы управления — «System_a1_500_ISOL», которые не оформляются в виде графических символов. Эти макромодели помещены в текстовый файл «user_model.txt» вместе с макромоделью «Most_500_ISOL» и автоматически вызываются системой Design из текста макромодели «Most_500_ISOL» по имени командой SIMULATE меню ANALYSIS на этапах проверки правил составления и создания списка соединений схемы, которые выполняются до начала расчета схемы.

Указанные процедуры всегда предшествуют началу расчета схемы, сопровождаются диагностикой ошибок и выполняются на уровне текстовых описаний. Если схема содержит большое количество графических символов, то при ее моделировании затрачивается дополнительное время на переход от символа к его текстовому описанию. Поэтому с точки зрения затрат машинного времени на выполнение расчетов концентрация нескольких текстовых описаний компонентов в рамках одного графического символа является предпочтительной.

Текстовое описание макромодели RC-цепи на языке программы PSpice имеет вид:

.SUBCKT RC  1  2  PARAMS:  R=1k C=1u
R_RC 1  p  {R}
C_RC p  2  {C} .
ENDS RC

Текстовое описание макромодели системы управления «System_a1_500_ISOL» по структуре не отличается от текстового описания макромодели системы управления «System_a1», поэтому дадим комментарии только к новым элементам текста:

.SUBCKT System_a1_500_ISOL
+ 1n 1p 2n 2p 3n 3p 4n 4p 5n 5p 6n 6p
+ PARAMS: Tu={T_puls} T0=0 A=30
+ Emin=-10 Emax=+15 Fr=50

* Fr=50 — значение частоты по умолчанию, размерность — Гц;

.FUNC F(x) (1/360)*x
VF1    1p    1n    PULSE    {Emin}    {Emax}
{F(T0/Fr+A/Fr)}
+ 10u 10u {F(Tu/Fr)} {1/Fr}
VF2    2p    2n    PULSE    {Emin}    {Emax}
{F(T0/Fr+A/Fr+60/Fr)}
+ 10u 10u {F(Tu/Fr)} {1/Fr} VF3 3p 3n PULSE {Emin} {Emax}
+ {F(T0/Fr+A/Fr+120/Fr)} 10u 10u {F(Tu/Fr)}
{1/Fr} VF4 4p 4n PULSE {Emin} {Emax}
+ {F(T0/Fr+A/Fr+180/Fr)} 10u 10u {F(Tu/Fr)}
{1/Fr} VF5 5p 5n PULSE {Emin} {Emax}
+ {F(T0/Fr+A/Fr+240/Fr)} 10u 10u {F(Tu/Fr)}
{1/Fr} VF6 6p 6n PULSE {Emin} {Emax}
+ {F(T0/Fr+A/Fr+300/Fr)} 10u 10u {F(Tu/Fr)}
{1/Fr} .ENDS System_a1_500_ISOL

Как видно из текста макромодели системы управления «System_a1_500_ISOL», его принципиальное отличие от текста макромодели системы управления «System_a1» состоит в том, что в перечень параметров введена частота. Последнее позволяет применять интегральный графический символ трехфазной мостовой схемы для моделирования преобразователей, работающих на любой частоте, как будет показано на примерах.

Следует отметить, что при обращении из текста основной схемы к встроенной макромодели выводам встроенной макромодели присваиваются маркировки, данные в тексте основной схемы, а при определении параметров приоритет отдается численным значениям идентификаторов параметров, вводимым в режиме диалога.

Вариация численных значений этих идентификаторов производится либо редактированием атрибутов графического символа, если данный идентификатор введен в атрибуты, либо с помощью атрибутов графического символа PARAM из штатной библиотеки SPECIAL.SLB системы Design в среде программы Schematics. Последний способ является более универсальным, так как позволяет одновременно изменять численные значения параметров нескольких компонентов схемы. В тексте макромоделей «Most_500_ISOL» и «System_a1_500_ISOL» идентификаторами заданы четыре параметра, определяющих режим работы силовой схемы:

T0={VALUE_TETA_0} — значение сдвига точки отсчета угла управления А относительно нуля системы координат;

Tu={T_puls} — значение длительности управляющего импульса;

A={VALUE_ALFHA} — значение угла управления;

Fr={VALUE_FREQ} — значение частоты.

Параметр «T0» имеет чисто математический смысл, так как определяет положение на оси абсцисс точки отсчета угла управления «А» относительно нуля системы координат.

В настоящей работе принято, что нулем системы координат является первая точка пересечения положительной полуволны э. д. с. источника питания Ea с осью абсцисс (рис. 17, см. «СЭ» № 4’2005).

Значение параметра «T0» зависит от фазы напряжения, приложенного непосредственно к вводу трехфазной мостовой схемы, которое зависит от схемы соединения обмоток питающего трансформатора. Так, для схемы трансформатора «звезда/звезда» значение параметра «T0» равно 30°, для схемы «звезда/треугольник» — равно нулю и т. д.

Отсюда следует, что параметр «T0» целесообразно вводить непосредственно в атрибуты графического символа трехфазной мостовой схемы, поскольку его редактирование выполняется однократно на этапе создания модели преобразователя в зависимости от фазы входного напряжения.

Параметры «Tu», «T0» и «Fr» определяют режимы работы преобразователя, поэтому в процессе исследования они могут меняться неоднократно. Кроме того, эти параметры часто надо вводить одновременно в макромодели нескольких компонентов схемы, например, нескольких мостов при исследовании многомостовой схемы. Поэтому для редактирования значений этих параметров целесообразно применять графический символ PARAM.

Покажем на примере, как реализуются данные технологии редактирования параметров.

Пример 3. Моделирование схемы тиристорного выпрямителя, выполненного по трехфазной мостовой схеме, на основе интегрального графического символа трехфазной мостовой схемы

В данном примере решается задача примера 2 (см. «СЭ», № 4’2005). Отличие состоит в применении более универсальных компонентов модели, которые позволяют эффективнее моделировать сложные схемы преобразовательной техники.

Вид интегрального графического символа трехфазной мостовой схемы и панель его атрибутов показаны на рис. 21.

В дополнение дадим полное описание шаблона TEMPLATE, так как оно в сочетании с графическим символом PARAM определяет механизм редактирования параметров интегрального графического символа трехфазной мостовой схемы:

TEMPLATE=X ^ @ REFDES %A %B %C %da %dk
+ @MODEL
+ PARAMS: VALUE_TETA_0=@ VALUE_TETA_0
+             VALUE_ALFHA={ ALFHA }
+             VALUE_FREQ ={ FREQ }

Символика шаблона в целом понятна из предыдущего комментария к атрибутам, поэтому поясним только часть после слова PARAMS:

• параметр VALUE_TETA_0 редактируется непосредственно на панели атрибутов, как показано на рис. 21, и передается в текст макромодели «Most_500_ISOL»;
• параметры ALFHA и FREQ редактируются с помощью графического символа PARAM, их значения присваиваются соответствующим идентификаторам и также передаются в текст макромодели «Most_500_ISOL». Что касается численного значения параметра

T_puls в тексте макромодели «System_a1_500_ISOL», то оно также редактируется с помощью графического символа PARAM и передается в текст макромодели непосредственно.

Отсюда видно, что возможны варианты применения графического символа PARAM для редактирования параметров.

Чертеж схемы тиристорного выпрямителя, выполненного по трехфазной мостовой схеме, на основе интегрального графического символа трехфазной мостовой схемы с применением графических символов PARAM показан на рис. 22. Отметим, что графический символ PARAM здесь применен также и для ввода действующего значения напряжения источников э. д. с. Ea, Eb, Ec, (TENS) и значения индуктивностей La2, Lb2, Lc2 (Lk).

Панель атрибутов графического символа PARAM показана на рис. 23, откуда понятна техника его применения для редактирования параметров.

Результаты моделирования схемы тиристорного выпрямителя, показанной на рис. 22, представлены на рис. 24, где обозначено: I(La2) — кривая тока в индуктивности La2; U(AS,M:dk) — напряжение на тиристоре VS1 трехфазной мостовой схемы. Форма и параметры данных кривых соответствуют их аналогам на рис. 20, что свидетельствует о корректности постановки и решения рассмотренной задачи.

3.5. Графические символы и макромодели трехфазных многообмоточных трансформаторов

Многообмоточные трансформаторы являются неотъемлемой частью мощных силовых полупроводниковых преобразователей.

В библиотеках системы Design отсутствуют встроенные модели таких трансформаторов, поэтому для исследования электромагнитных процессов в схемах силовых полупроводниковых преобразователей необходимо предварительно создать типовые модели и графические символы многообмоточных трансформаторов.

Данная задача решается с помощью методик разработки макромоделей на языке программы PSpice и редактирования символов компонентов в программе Schematics.

Макромодели трансформаторов составляются на основе встроенных моделей управляемых источников напряжения и тока.

Разработаны макромодели трехфазных двух-обмоточных, трехобмоточных и пятиобмоточных трансформаторов [8, 11].

Двухобмоточные трансформаторы выполнены по схемам: «звезда/звезда»; «звезда/треугольник» со сдвигом системы вторичных напряжений на +30° и -30° относительно системы первичных напряжений.

Трехобмоточные трансформаторы выполнены по схеме: «звезда/звезда— треугольник» со сдвигом системы вторичных напряжений «треугольника» относительно системы вторичных напряжений «звезды» на + 30° и -30°.

Пятиобмоточный трансформатор выполнен по схеме «звезда/звезда — треугольник — зигзаг1 — зигзаг2» со сдвигом систем напряжений обмоток 0°, 0°, -30°, +15°, -15° соответственно.

Общий подход к разработке макромоделей трехфазных многообмоточных трансформаторов состоит в следующем.

Вначале составляются схемы замещения первичной и вторичных обмоток трансформатора.

Схема замещения первичной обмотки представляет собой трехфазный комплект управляемых источников тока, соединенных между собой в соответствии с реальной схемой моделируемой обмотки.

Каждая вторичная обмотка представляется собственной схемой замещения. Каждая фаза схемы замещения вторичной обмотки моделируется последовательным соединением управляемого источника напряжения и независимого источника напряжения. Величина напряжения независимого источника принята равной нулю. Фазы каждой схемы замещения вторичной обмотки соединены между собой в соответствии с реальной схемой моделируемой обмотки.

Величина тока в фазе схемы замещения первичной обмотки равна сумме токов, протекающих через независимые источники напряжения в соответствующих фазах схем замещения вторичных обмоток и умноженных на коэффициент трансформации.

Величина разности потенциалов на зажимах управляемого источника напряжения в фазах каждой схемы замещения вторичной обмотки равна разности потенциалов на зажимах управляемого источника тока в соответствующей фазе схемы замещения первичной обмотки, умноженной на коэффициент трансформации.

Влияние схем соединения вторичных обмоток на величину токов в фазах первичной обмотки и разности потенциалов на зажимах управляемого источника напряжения в фазах вторичных обмоток учитывается с помощью коэффициентов и дополнительных составляющих в функции управления указанными источниками тока и напряжения.

Реактансы рассеяния обмоток трансформатора вводятся в схему преобразователя.

Рассмотрим технологию разработки макромодели многообмоточного трансформатора на примерах трехфазного двухобмоточного трансформатора, выполненного по схеме «звезда/треугольник» со сдвигом системы вторичных напряжений на +30° относительно системы первичных напряжений, и пятиобмо-точного трансформатора.

Принципиальная схема двухобмоточного трансформатора в виде чертежа графического символа показана на рис. 25, где обозначено:

• TV — условное обозначение трансформатора на чертежах схем в среде программы Schematics;
• A1, B1, C1, p0 — обозначения выводов первичной обмотки;
• A2, B2, C2 — обозначения выводов вторичной обмотки.
• Схемы замещения первичной и вторичной обмоток на элементной базе встроенных моделей системы Design показаны на рис. 26, 27 соответственно, где обозначено:

• VA22, VB22, VC22 — независимые источники напряжения;
• GA1, GB1, GC1 — источники тока, управляемые током через независимые источники напряжения VA22, VB22, VC22 соответственно;
• EA22, EB22, EC22 — источники напряжения, управляемые напряжением, приложенным к источникам тока GA1, GB1, GC1 соответственно. Описание макромодели трансформатора на языке программы PSpice, соответствующее его схеме замещения на рис. 26, 27, имеет следующий вид:

.SUBCKT TV_3f_m3 A1 B1 C1 p0
+             A2  B2  C2
+             PARAMS: K=1 R=10k RT=0.001
+             n1=1.732050807569

• .SUBCKT — директива начала описания макромодели;
• TV_3f_m3 — имя макромодели;
• A1 B1 C1 p0 A2 B2 C2 — маркировки узлов трансформатора;
• PARAMS: — ключевое слово, после которого приводится перечень параметров макромодели;
• K — коэффициент трансформации;
• R — сопротивление, кОм;
• RT — сопротивление, Ом;
• «+» — знак продолжения строки.

GA1 A1 p0 VALUE={K*n1*I(VA22)}
GB1 B1 p0 VALUE={K*n1*I(VB22)}
GC1 C1 p0 VALUE={K*n1*I(VC22)}

• три предложения, описывающие включение источников тока в схему по рис. 26, и функции, определяющие значения токов источников:
• GA1, GB1, GC1 — имена источников;
• A1, B1, C1, p0 — маркировки узлов;
• VALUE — ключевое слово, после которого приводится описание функции;
• I(VA22), I(VB22), I(VC22) — токи, протекающие через независимые источники напряжения VA22, VB22, VC22 соответственно.

EA22 p2A22 p1A22 VALUE={K*n1*V(A1,p0)}
EB22 p2B22 p1B22 VALUE={K*n1*V(B1,p0)}
EC22 p2C22 p1C22 VALUE={K*n1*V(C1,p0)}

*       три предложения, описывающие включение управляемых источников напряжения в схему по рис. 27, и функции, определяющие значения напряжений источников:

• EA22, EB22, EC22 — имена источников;
• p2A22, p1A22, p2B22, p1B22, p2C22, p1C22 — маркировки узлов;
• VALUE — ключевое слово, после которого приводится описание функции;
• V(A1,p0), V(B1,p0) V(C1,p0) — разности потенциалов на зажимах управляемых источников тока GA1, GB1, GC1 соответственно.

VA22 p2A22 A2 0
VB22 p2B22 B2 0
VC22 p2C22 C2 0

• три предложения, описывающие включение независимых источников напряжения в схему по рис. 27 и их параметры:
• VA22, VB22, VC22 — имена источников;
• p2A22, A2, p2B22, B2, p2C22, C2 — маркировки узлов;
• 0 — значение напряжения, В.

RTA22 p1A22  C2 {RT}
RTB22 p1B22  A2 {RT}
RTC22 p1C22  B2 {RT}

• три предложения, описывающие включение сопротивлений в схему по рис. 27 и их параметры:
• RTA22, RTB22, RTC22 — имена сопротивлений;
• p1A22, C2, p1B22, A2, p1C22, B2 — маркировки узлов;
• {RT} — значения сопротивлений, заданные идентификатором, Ом.

RA22 A2 0 {R}
RB22 B2 0 {R}
RC22 C2 0 {R}

• три предложения, описывающие включение сопротивлений в схему по рис. 27 и их параметры (эти сопротивления на схеме не указаны, введены для обеспечения сходимости решения задач, в которых используется данная макромодель):
• RA22, RB22, RC22 — имена сопротивлений;
• A2, B2, C2, 0 — маркировки узлов;
• {R} — значения сопротивлений, заданные идентификатором, кОм.

.ENDS   TV_3f_m3

• .ENDS — директива окончания описания макромодели;
• TV_3f_m3 — имя макромодели. Макромодель является одним из параметров

графического символа («атрибутов» по терминологии, принятой в описаниях системы Design), с помощью которых осуществляется вывод информации о компоненте на чертеж принципиальной схемы в программе Schematics и передача информации о компоненте в программу PSpice.

Полный список атрибутов графического символа данного трансформатора имеет следующий вид:

PART=Trans_3f_m3

• PART — шаблон имени символа компонента, под которым он заносится в библиотеку символов;
• Trans_3f_m3 — имя символа компонента.

PKGREF=TV1

• PKGREF — шаблон позиционного обозначения компонента;
• 1 — позиционное обозначение компонента на чертеже схемы, созданной в программе Schematics;
• TV1 — имя компонента.

REFDES=TV1

• REFDES — шаблон префикса условного обозначения компонента;
• TV — префикс условного обозначения компонента на чертеже схемы, созданной в программе Schematics;

*       TV1 — имя компонента.

TEMPLATE=X ^ @ REFDES %A1 %B1 %C1%p0 %A2
+ %B2 %C2 @MODEL PARAMS: K=@K

• TEMPLATE — шаблон для назначения соответствий графических выводов компонента с их реальным физическим смыслом и задания параметров компонента;
• X — символ имени компонента, соответствующий макромодели;
• ^ — знак, который в процессе работы системы Design заменяется указанием полного пути доступа к компоненту;
• @ — знак, указывающий на то, что следующий за ним шаблон в процессе работы системы Design заменяется его именем;
• % — знак, предваряющий имя вывода компонента;
• MODEL — шаблон, обозначающий наличие описания модели или макромодели компонента;
• PARAMS: — шаблон, после которого вводятся параметры;

MODEL= TV_3f_m3

• MODEL — шаблон имени модели или макромодели компонента;
• TV_3f_m3 — имя макромодели компонента.

K=1

• K — имя параметра (коэффициент трансформации);
• 1 — значение параметра, которое может редактироваться.

Пример 4. Моделирование схемы тиристорного выпрямителя с использованием графического символа трехфазного двухобмоточного трансформатора, выполненного по схеме «звезда/треугольник»

На рис. 28 дан чертеж схемы тиристорного выпрямителя, составленный в среде программы Schematics, где обозначено:

• Ea, Eb, Ec — символы источников э. д. с. переменного тока, действующее значение напряжения — 220 В;
• La, Lb, Lc — символы индуктивностей питающей сети;
• TV1 — символ трансформатора;
• LA1, LB1, LC1 — символы индуктивностей первичной обмотки трансформатора;
• LA2, LB2, LC2 — символы индуктивностей вторичной обмотки трансформатора;
• М1 — символ трехфазного мостового тиристорного выпрямителя;
• Ld — символ индуктивности сглаживающего реактора, значение — 10 мГн;
• Rd — символ активного сопротивления нагрузки, значение — 5 Ом;
• Ed — символ источника э. д. с. постоянного тока, значение напряжения — 10 В;
• V — маркер напряжения в указанной точке схемы относительно «0»;
• I — маркер тока в указанной ветви схемы;
• PARAMETRS — специальный символ, предназначенный для задания и изменения параметров схемы:

• • Ls = 10 мкГн — значение La, Lb, Lc;
  • L1 = 10 мкГн — значение LA1, LB1, LC1;
  • L2 = 1 мкГн — значение LA2, LB2, LC2;
  • ALPFA= 30 — значение угла управления выпрямителя, град;
  • T_puls = 90 — значение длительности импульса управления, град.

Результаты расчета, полученные с помощью программы PSpice и обработанные в среде программы Probe, показаны на рис. 29.

Условные обозначения на рис. 29:

• V(LA1:1) — напряжение на выводе первичной обмотки трансформатора, фаза А;
• V(LA2:1) — напряжение на выводе вторичной обмотки трансформатора, фаза А;
• I(LA1) — ток в индуктивности LA1;
• I(LA2) — ток в индуктивности LA2.

Как видно из рис. 29, эпюры токов точно совпадают с известными в теории преобразовательной техники кривыми, что свидетельствует об адекватном отображении в разработанной модели трансформатора параметров его физического прототипа.

Рассмотрим макромодель пятиобмоточного трансформатора, выполненного по схеме «звезда/звезда — треугольник — зигзаг1 — зигзаг2» со сдвигом систем напряжений обмоток 0°, 0°, -30°, -15°, +15° соответственно.

Схемы замещения первичной обмотки и вторичных обмоток трансформатора показаны на рис. 30, 31, 32, 33, 34. Описание макромодели трансформатора на языке программы PSpice, соответствующее данным схемам замещения, имеет следующий вид:

.SUBCKT      TV_12f_m1  A1  B1   C1  p0
+            A21  B21   C21
+            A22  B22 C22
+            A23 B23  C23
+            A24 B24  C24
+        PARAMS:   K=1 RT=0.001
+                  n1=1.732050807569
+                  n2=0.8164965809277
+                  n=0.2988584907227

• .SUBCKT — директива начала описания макромодели;
• TV_12f_m1 — имя макромодели;
• A1, B1, C1, p0, A21, B21, C21, A22, B22, C22, A23, B23, C23, A24, B24, C24 — маркировки выводов обмоток трансформатора;
• «+» — знак продолжения строки;
• PARAMS: — ключевое слово, после которого приводится перечень параметров макромодели;
• K — коэффициент трансформации;
• RT — сопротивление, Ом;
• n1, n2, n3 — коэффициенты корректировки составляющих тока и напряжения управляемых источников в зависимости от схемы соединения вторичной обмотки.
• Описание первичной обмотки:

GA1 A1 p0 VALUE={K*(I(VA21)+n1*I(VA22)
+         +n2*I(VA23)-n3*I(VB23)
+         +n2*I(VA24)-n3*I(VC24))}
GB1 B1 p0 VALUE={K*(I(VB21)+n1*I(VB22)
+         +n2*I(VB23)-n3*I(VC23)
+         +n2*I(VB24)-n3*I(VA24))}
GC1 C1 p0 VALUE={K*(I(VC21)+n1*I(VC22)
+         +n2*I(VC23)-n3*I(VA23)
+         +n2*I(VC24)-n3*I(VB24))}

• три предложения, описывающие включение управляемых источников тока в схему по рис. 30, и функции, определяющие значения токов источников:
• GA1, GB1, GC1 — имена источников;
• A1, B1, C1, p0 — маркировки узлов;
• VALUE— ключевое слово, после которого приводится описание функции, определяющей значение тока управляемого источника тока;
• I(VA21)…I(VA24), I(VB21)…I(VB24), I(VC21)…I(VC24) — токи, протекающие через независимые источники напряжения VA21… VA24, VB21… VB24, VC21… VC24 соответственно.

Описание вторичной обмотки «звезда»:

EA21 p1A21 p021 VALUE={K*V(A1,p0)}
EB21 p1B21 p021 VALUE={K*V(B1,p0)}
EC21 p1C21 p021 VALUE={K*V(C1,p0)}

• три предложения, описывающие включение управляемых источников напряжения в схему по рис. 31, и функции, определяющие значения напряжения этих источников:
• EA21, EB21, EC21 — имена источников;
• p1A21, p1B21, p1C21, p021 — маркировки узлов;
• VALUE — ключевое слово, после которого приводится описание функции;
• V(A1,p0), V(B1,p0) V(C1,p0) — разности потенциалов на зажимах управляемых источников тока GA1, GB1, GC1 соответственно по рис. 30.

VA21 p1A21 A21 0
VB21 p1B21 B21 0
VC21 p1C21 C21 0

• три предложения, описывающие включение независимых источников напряжения в схему по рис. 30 и их параметры:
• VA21, VB21, VC21 — имена источников;
• p1A21, A21, p1B21, B21, p1C21, C21 — маркировки узлов;

*       0 — значение напряжения, В. Описание вторичной обмотки «треугольник»:

EA22 p2A22 p1A22 VALUE={K*n1*V(A1,p0)}
EB22 p2B22 p1B22 VALUE={K*n1*V(B1,p0)}
EC22 p2C22 p1C22 VALUE={K*n1*V(C1,p0)}
VA22 p2A22 A22    0
VB22 p2B22 B22    0
VC22 p2C22 C22    0

*       шесть предложений, описывающих включение и параметры управляемых и независимых источников напряжения в схему по рис. 32; синтаксис данных предложений аналогичен синтаксису соответствующих предложений в описании вторичной обмотки «звезда».

RTA22 p1A22 B22 {RT}
RTB22 p1B22 C22 {RT}
RTC22 p1C22 A22 {RT}

• три предложения, описывающие включение сопротивлений в схему по рис. 32 и их параметры:
• RTA22, RTB22, RTC22 — имена сопротивлений;
• p1A22, C2, p1B22, A2, p1C22, B2 — маркировки узлов;
• {RT} — идентификатор параметра RT; по умолчанию принимает значение, указанное в заголовке макромодели после ключевого слова PARAMS.

Описание вторичной обмотки «зигзаг1»:

EA23 p1A23 p023 VALUE={K*(n2*V(A1,p0)-n3*V(C1,p0))}
EB23 p1B23 p023 VALUE={K*(n2*V(B1,p0)-n3*V(A1,p0))}
EC23 p1C23 p023 VALUE={K*(n2*V(C1,p0)-n3*V(B1,p0))}
VA23 p1A23 A23 0
VB23 p1B23 B23 0
VC23 p1C23 C23 0

*       шесть предложений, описывающих включение и параметры управляемых и независимых источников напряжения в схему по рис. 33; синтаксис данных предложений аналогичен синтаксису соответствующих предложений в описании вторичной обмотки «звезда».

Описание вторичной обмотки «зигзаг2»:

EA24 p1A24 p024 VALUE={K*(n2*V(A1,p0)-n3*V(B1,p0))}
EB24 p1B24 p024 VALUE={K*(n2*V(B1,p0)-n3*V(C1,p0))}
EC24 p1C24 p024 VALUE={K*(n2*V(C1,p0)-n3*V(A1,p0))}
VA24 p1A24 A24 0
VB24 p1B24 B24 0
VC24 p1C24 C24 0

*       шесть предложений, описывающих включение и параметры управляемых и независимых источников напряжения в схему по рис. 34; синтаксис данных предложений аналогичен синтаксису соответствующих предложений в описании вторичной обмотки «звезда».

.ENDS   TV_12f_m1

• .ENDS — директива окончания описания макромодели;
• TV_12f_m1 — имя макромодели. Описание списка атрибутов графического

символа пятиобмоточного трансформатора прокомментируем только в части атрибута TEMPLATE, остальные атрибуты аналогичны атрибутам графического символа двухобмоточного трансформатора:

PART=Trans_12f_m1_dubl
PKGREF=TV1
REFDES= TV1
TEMPLATE=X ^ @ REFDES %A1 %B1 %C1% %A21
+ %B21 %C21%A22 %B22 %C22%A23 %B23 %C23%
+A24 %B24 %C24 @MODEL PARAMS: K={K}

• TEMPLATE — шаблон для назначения соответствий графических выводов компонента с их реальным физическим смыслом и задания параметров компонента;
• X — символ имени компонента, соответствующий макромодели;
• ^ — знак, который в процессе работы системы Design заменяется указанием полного пути доступа к компоненту;
• @ — знак, указывающий на то, что следующий за ним шаблон в процессе работы системы Design заменяется его именем;
• % — знак, предваряющий имя вывода компонента;
• MODEL — шаблон, обозначающий наличие описания модели или макромодели компонента;
• PARAMS: K={K} — шаблон, после которого вводятся параметры;
• K — имя параметра (коэффициент трансформации);
• {K} — идентификатор значения параметра K, для задания этого значения используется графический символ PARAM из библиотеки special.slb, содержащей директивы задания на моделирование.

MODEL= TV_12f_m1

Чертеж графического символа пятиобмоточного трансформатора и панель его атрибутов показаны на рис. 35.

Маркировки выводов графического символа на чертеже не показаны, чтобы избежать при моделировании схем с пятиобмоточными трансформаторами избыточной информации на чертеже схемы. Четыре верхних вывода соответствуют вводам первичной обмотки A1, B1, C1, p0, отсчет — справа налево. Нижние выводы соответствуют выводам вторичных обмоток, по три вывода на обмотку. Первые три вывода соответствуют выводам обмотки «звезда» A21, B21, C21, отсчет — справа налево, и т. д.

Отметим, что на панели атрибутов в окне редактирования показан последний элемент шаблона TEMPLATE : K={K}, что позволяет редактировать его с помощью графического символа PARAM.

Пример 5. Моделирование схемы четырехмостового тиристорного выпрямителя

Цель данного примера — тестирование результатов расчета путем сопоставления с экспериментальными данными, полученными автором в процессе промышленных испытаний мощных двадцатичетырехпульсных преобразователей [12, 13, 14].

Функциональная схема модели показана на рис. 36.

Параметры силовой схемы соответствуют параметрам стенда, на котором под руководством и при участии автора проводились натурные испытания влияния двадцатичетырех-пульсного преобразователя на питающую сеть, и имеют следующие значения:

• Ea = Eb = Ec = 6300 В;
• La = Lb = Lc = Ls= 40 мГн ;
• LA21 ….LC24 = L2 = 2 мГн;
• Ld = 50 мГн; Rd = 20 Ом.

Параметры системы управления имеют следующие значения:

• A (угол управления) = 30 электрических градусов;
• Tu (длительность управляющего импульса) = 110 электрических градусов;

•     T0 (сдвиг точки отсчета угла управления А относительно нуля системы координат): для моста М1 — 30 электрических градусов; для моста М2 — 60 электрических градусов; для моста М3 — 45 электрических градусов; для моста М4 — 15 электрических градусов. В результате моделирования рассчитывались эпюры токов во всех ветвях функциональной схемы, эпюры потенциалов всех узлов относительно нуля функциональной схемы; производился гармонический анализ заданных кривых тока и напряжения.

Для тестирования выбраны следующие результаты расчета: эпюры тока и напряжения на входе моста М1 (рис. 37); эпюры тока и напряжения на входе преобразователя (рис. 38); результаты гармонического анализа эпюры тока на входе моста М1 и эпюры напряжения на входе преобразователя (рис. 39).

Эпюры тока и напряжения на входе моста М1 и результаты гармонического анализа эпюры тока в точности совпадают с известными теоретическими результатами [15].

Эпюры тока и напряжения на входе преобразователя и результаты гармонического анализа эпюры напряжения сопоставлены с экспериментальными данными (рис. 39, 40) и также удовлетворительно совпадают, учитывая погрешности проведения эксперимента в условиях действующего производства.

Таким образом, тестирование результатов моделирования путем сопоставления с экспериментальными данными свидетельствует о корректности предложенных графических символов пятиобмоточного трансформатора и модели в целом.

Все статьи цикла